<%
	set CLASS_cLink = new CLink
	set CLASS_cCategory = new CCategory
	set CLASS_cEmail = new CEmail
	set CLASS_cEmailtemplate = new CEmailtemplate
%>
<%
		'Load Link/Item Data that we saved prior
		'----------------------------------------
		CLASS_cLink.LoadFromID(CLASS_cPayment.IDOwner)
		
		'----------------------------
		'Payment Status Handling
		'----------------------------
		Select Case lcase(CLASS_cPayment.PaymentStatus)
'			case "fail"
				'Do Nothing - Should never get here, Fail was handled earlier
			case "success"
				'Set it to active now they've payed - we set approved before hand when we first saved (prior to payment gateway)
				CLASS_CLink.Active = True
				CLASS_cLink.StoreData		
			case "sub-cancel"
				'Get period we are currently in (cancel date)
				'CLASS_cPayment.FindRecurringPeriod(CLASS_cPayment.recurringdatestart, CLASS_cPayment.recurringdateend,CLASS_cPayment.RecurringTimePeriod,CLASS_cPayment.RecurringTimePeriodUnit) 
				'Calculate how long left this subscription has to run and save final end date
				CLASS_cPayment.RecurringDateEnd = CLASS_cPayment.CalculateRecurringDateEnd(CLASS_cPayment.recurringdatestart,CLASS_cPayment.RecurringTimePeriod,CLASS_cPayment.RecurringTimePeriodUnit,CLASS_cPayment.FindRecurringPeriod(CLASS_cPayment.recurringdatestart, CLASS_cPayment.recurringdateend,CLASS_cPayment.RecurringTimePeriod,CLASS_cPayment.RecurringTimePeriodUnit))
'			case "pending"
				'Do Nothing - dont activate until successs
		End Select
		'Store Payment Details or Update - ID Found in notify statement, if id, then update
		'-----------------------
		CLASS_cPayment.StoreData 'Save



		'----------------------------
		'Email
		'----------------------------
		Select Case lcase(CLASS_cPayment.PaymentStatus)
'			Case "fail"
			
			Case "success"
				'Load category based on the parent ID, to get category information for emails
				CLASS_cCategory.LoadFromID(CLASS_cLink.idparent)
				'Get complete hierarchy of category location, to place in emails. 
				CLASS_cCategory.categorylocation = CLASS_cCategory.getHTMLLocation(CLASS_cLink.idparent)
		
				'Email Setup
				CLASS_cEmail.EmailComponent=CONFIG.Setting("EmailComponent")
				CLASS_cEmail.EmailServerName=CONFIG.Setting("EmailServerName")
				CLASS_cEmail.EmailFormat=CONFIG.Setting("EmailFormat")	

				'Email to Admin - Link Activated
				if CONFIG.Setting("NotifyAdministrator") = True then
					CLASS_cEmail.EmailFrom=CLASS_cLink.ContactEmail
					CLASS_cEmail.EmailTo=CONFIG.Setting("AdministratorsEmail")
					
					If CONFIG.Setting("AutomaticApproval") = True Then
						CLASS_cEmailTemplate.LoadFromTemplateName("New Link Added And Approved")
					Else
						CLASS_cEmailTemplate.LoadFromTemplateName("New Link Added And Needs Approval")
					End If
					CLASS_cEmail.EmailSubject=CONFIG.Setting("META_SiteTitle") & ": "&CLASS_cEmailTemplate.subject&" " & CLASS_cLink.linkname
					CLASS_cEmail.EmailBody = CLASS_cEmailTemplate.header&CLASS_cEmailTemplate.content
					%>
						<!--#include file="email_admin.asp"-->
					<%
					CLASS_cEmail.EmailBody=CLASS_cEmail.EmailBody & CLASS_cEmailTemplate.footer
					CLASS_cEmail.sendEmail 'Send an email to administrator
					
					'Send order status/summary to administrator
					CLASS_cEmail.EmailSubject=CONFIG.Setting("META_SiteTitle")&": "&CLASS_cLink.linkname&" Order Summary :"&CLASS_cPayment.PaymentStatus
					CLASS_cEmail.EmailBody=CLASS_cPayment.StatusMessage(CLASS_cPayment.IDType,"notify")
					CLASS_cEmail.sendEmail
				End If
			
				'Send a copy to the person who submitted the link
				CLASS_cEmail.EmailFrom=CONFIG.Setting("AdministratorsEmail")
				CLASS_cEmail.EmailTo=CLASS_cLink.ContactEmail
				If CONFIG.Setting("AutomaticApproval") = True Then
					CLASS_cEmailTemplate.LoadFromTemplateName("New Link Added And Approved User")
				Else
					CLASS_cEmailTemplate.LoadFromTemplateName("New Link Added And Needs Approval User")
				End If
				CLASS_cEmail.EmailSubject=CONFIG.Setting("META_SiteTitle") & ": "&CLASS_cEmailTemplate.subject&" " & CLASS_cLink.linkname
				CLASS_cEmail.EmailBody = CLASS_cEmailTemplate.header&CLASS_cEmailTemplate.content
				%>
				<!--#include file="email_user.asp"-->
				<%
				CLASS_cEmail.EmailBody=CLASS_cEmail.EmailBody & CLASS_cEmailTemplate.footer
				CLASS_cEmail.sendEmail
		
				'Send order status/summary to user
				CLASS_cEmail.EmailSubject=CONFIG.Setting("META_SiteTitle")&": "&CLASS_cLink.linkname&" Order Summary : "&CLASS_cPayment.PaymentStatus
				CLASS_cEmail.EmailBody=CLASS_cPayment.StatusMessage(CLASS_cPayment.IDType,"notify")
				CLASS_cEmail.sendEmail
			
			'----------------------------
			'Subscription Cancel
			'----------------------------
			Case "sub-cancel"
				'Email Setup
				CLASS_cEmail.EmailComponent=CONFIG.Setting("EmailComponent")
				CLASS_cEmail.EmailServerName=CONFIG.Setting("EmailServerName")
				CLASS_cEmail.EmailFormat=CONFIG.Setting("EmailFormat")	

				'Email to Admin - Link Activated
				if CONFIG.Setting("NotifyAdministrator") = True then
					CLASS_cEmail.EmailFrom=CLASS_cLink.ContactEmail
					CLASS_cEmail.EmailTo=CONFIG.Setting("AdministratorsEmail")
					CLASS_cEmailTemplate.LoadFromTemplateName("Subscription Cancellation")

					CLASS_cEmail.EmailSubject=CONFIG.Setting("META_SiteTitle")&": "&CLASS_cEmailTemplate.subject&": "&CLASS_cPayment.PaymentStatus
					CLASS_cEmail.EmailBody = CLASS_cEmailTemplate.header&CLASS_cEmailTemplate.content
					CLASS_cEmail.EmailBody=CLASS_cEmail.EmailBody & CLASS_cPayment.StatusMessage(CLASS_cPayment.IDType,"notify")
					CLASS_cEmail.EmailBody=CLASS_cEmail.EmailBody & CLASS_cEmailTemplate.footer
					CLASS_cEmail.sendEmail 'Send an email to administrator
				End If
			
				'Send a copy to the person who submitted the link
				CLASS_cEmail.EmailFrom=CONFIG.Setting("AdministratorsEmail")
				CLASS_cEmail.EmailTo=CLASS_cLink.ContactEmail
				CLASS_cEmailTemplate.LoadFromTemplateName("Subscription Cancellation")

				CLASS_cEmail.EmailSubject=CONFIG.Setting("META_SiteTitle")&": "&CLASS_cEmailTemplate.subject&": "&CLASS_cPayment.PaymentStatus
				CLASS_cEmail.EmailBody = CLASS_cEmailTemplate.header&CLASS_cEmailTemplate.content
				CLASS_cEmail.EmailBody=CLASS_cEmail.EmailBody & CLASS_cPayment.StatusMessage(CLASS_cPayment.IDType,"notify")
				CLASS_cEmail.EmailBody=CLASS_cEmail.EmailBody & CLASS_cEmailTemplate.footer
				CLASS_cEmail.sendEmail
		'	Case "pending"
		End Select
	
%>
<%
set CLASS_cLink = nothing
set CLASS_cCategory = nothing
set CLASS_cEmail = nothing
set CLASS_cEmailtemplate = nothing
%>